Измерение уровня заряда аккумулятора на Ардуино

Отслеживание уровня заряда аккумулятора или батареи является одной из основных задач при разработке автономных устройств. Особенно она актуальна для устройств, которые работают удалённо и сообщают о своём статусе, используя, например, GSM канал*. Даже когда устройство находится рядом с вами, индикация уровня заряда аккумулятора поможет сделать его использование более удобным. В данной статье мы рассмотрим простой способ отслеживания уровня заряда аккумулятора или батареи при помощи Ардуино.

*Знакомые с GSM модулями могут возразить, что в их составе уже присутствуют средства мониторинга заряда аккумулятора, и не нужно изобретать велосипед. Справедливое замечание. Но при условии, что для GSM модуля не используется стабилизация напряжения, скажем, от 12-вольтового аккумулятора. В этом случае модуль не сможет оценить уровень заряда аккумулятора. Таким образом, не стоит преуменьшать актуальность данной темы.

Теория

Предлагаемый способ отслеживания уровня заряда основан на измерении напряжения источника питания. Возьмем, к примеру, литий-ионный аккумулятор. В процессе разрядки его напряжение изменяется от 4.2 В до 3 В. Выполняя периодические замеры напряжения и сопоставляя полученный результат с приведённым диапазоном 4.2...3 В, мы можем оценить уровень заряда. Но не всё так однозначно. Дело в том, что напряжение аккумулятора при разряде изменяется не линейно. Это видно из графика разряда литий-ионного аккумулятора, который легко найти в google по запросу li-ion discharge graph:

Данный график позаимствован с сайта batteryuniversity. На нём отражён процесс разряда аккумулятора Panasonic NCR18650B 3200мАч разными токами от 0.2C до 2C. Как видите, напряжение аккумулятора изменяется более-менее линейно лишь при разряде большими токами. Здесь можно вспомнить математику и посчитать процент оставшегося заряда по линейной формуле. Но это, скорее, частный случай. Пожалуй, более актуальны случаи, когда устройство потребляет незначительные токи, поэтому ориентироваться мы будем на красную и синюю кривые.

Таким образом, чтобы получить наиболее точное представление об оставшемся заряде аккумулятора или батареи на основе напряжения, нужно иметь соответствующий график разряда.

Следующий момент, который я беру во внимание – это то, что высокая детализация уровня заряда (в тех же процентах, которые дают нам 100 значений) бывает нужна крайне редко. В большинстве случаев достаточно понимания: когда уровень заряда находится в "зелёной зоне", когда в "жёлтой", а когда нужно быть готовым к отключению устройства из-за разряда аккумулятора. Поэтому наиболее рациональным представляется подход, когда мы выделяем 3-4 пороговых напряжения и относительно них определяем уровень заряда. Грубо говоря, если напряжение литий-ионного аккумулятора больше 4 В, то заряд высокий; если меньше 3.2 В – аккумулятор вот-вот разрядится, а между этими двумя значениями выделяем еще несколько зон. Если необходимо выразить заряд именно в процентах – пожалуйста: выделяем 10 зон и показываем результат десятками (10%, 20% и т.д.).

Аналогичные графики разряда можно найти и для других элементов питания, смысл будет тот же.

Реализация

Итак, задача поставлена: необходимо измерять напряжение источника питания нашего устройства. Я бы выделил 2 возможных варианта реализации:

• измерять напряжение, используя АЦП Ардуино;
• воспользоваться датчиком напряжения, например, INA219.

Первый вариант хорош тем, что для него ничего не требуется. Разве что пара резисторов. А датчик напряжения – это уже дополнительный компонент. Зато он позволит более точно измерять напряжение. Кроме того INA219 измеряет потребляемый ток и мощность, поэтому имеет потенциал для дальнейшего развития в плане мониторинга питания (с его помощью можно построить ту же кривую разряда аккумулятора, определить его ёмкость, спрогнозировать время работы устройства), но это уже отдельная тема.

Вариант 1. Измерение напряжения при помощи Ардуино.

Все платы Ардуино имеют в своём составе АЦП. У популярных плат (UNO, NANO, MEGA2560) разрядность АЦП составляет 10 бит, у более продвинутых (Due, Zero) – 12 бит. АЦП позволяет измерять напряжение в диапазоне от 0 В до опорного напряжения Vref. Значение Vref в общем случае соответствует напряжению питания платы – 5 В или 3.3 В, но может быть привязано к внутреннему стабилизатору. Для лучшего понимания принципов использования АЦП предлагаю рассмотреть следующий скетч.

void setup() {
  Serial.begin(9600);
}

void loop() {
  int v = analogRead(A0); 
  Serial.println(v);
  delay(1000);
}

Загрузите скетч в Ардуино, соедините A0 с выводом 5V и откройте монитор порта. Вы должны увидеть следующий результат:

Этот скетч измеряет напряжение на входе A0 и выводит результат в монитор порта. Разрешение АЦП используемой мной Ардуино УНО составляет 10 бит, а значит, результатом измерений будет число от 0 до 1023 (2^10 значений). При этом значение 0 будет говорить об отсутствии напряжения, а максимальное значение – 1023 – о его равенстве (а так же превышении, что мы не будем рассматривать) опорному напряжению Vref, каким бы оно ни было. У меня в монитор порта выводится как раз число 1023. Поскольку опорным напряжением АЦП по умолчанию является напряжение питания Ардуино – 5 вольт, выдаваемые USB портом компьютера (разумеется, это не точное значение), можно утверждать, что напряжение на входе A0 тоже составляет 5 вольт.

Попробуем отсоединить A0 от вывода 5V и подсоединить к 3v3. Теперь у меня в монитор порта выводится значение 687. Зная опорное напряжение, нетрудно вычислить напряжение на A0:

(5 В / 1024) * 687 = 3.35 В

Для получения более точного результата следует измерить напряжение, выдаваемое USB портом.

Если же вывод A0 соединить с «землёй», то в монитор порта будет выводиться значение 0.

Вернёмся к нашей задаче. Питание от аккумулятора не всегда предполагает наличие стабильного напряжения, которое может использоваться как опорное для АЦП. В таких случаях в качестве Vref следует использовать напряжение от внутреннего стабилизатора Ардуино. Для большинства плат, в том числе Ардуино УНО, это напряжение составляет 1.1 В. Это означает, что измеряемое напряжение необходимо понизить при помощи делителя, чтобы оно не превышало 1.1 В. Здесь нам помогут пара резисторов номиналом в несколько десятков-сотен кОм, включенные по следующей схеме:

Это простейший резистивный делитель напряжения. Он характеризуется коэффициентом передачи, который показывает, во сколько раз выходное напряжение будет меньше входного, то есть:

Uвых = K * Uвх

Сам коэффициент рассчитывается по следующей формуле:

K = R2 / (R1 + R2)

Остаётся лишь подобрать номиналы резисторов таким образом, чтобы понизить напряжение аккумулятора до нужного нам уровня. Для измерения напряжения аккумулятора 18650 я выбрал номиналы 47k и 10k. Реальное сопротивление будет отличаться, поэтому их нужно обязательно измерить мультиметром. Выбранные мной номиналы дают коэффициент ~0.175, что позволяет измерять напряжение до 1.1 В / 0.175 = 6,27 В. Ниже приведены схема, пример скетча, реализующий описанный функционал, и результат его работы. Предполагается, что Ардуино питается от аккумулятора, поэтому результаты выводятся на дисплей 1602, а не в Serial.

#include "Wire.h"
#include "LiquidCrystal_I2C.h"
LiquidCrystal_I2C lcd(0x27, 16, 2);

// Номиналы резисторов, измеренные мультиметром:
const float R1 = 46600.0; // 47k
const float R2 = 9981.0;  // 10k

const float divider = R2/(R1 + R2); // Коэффициент передачи
const float Vref = 1.1; // Опорное напряжение

// Пороговые напряжения для 18650. Можно изменять/дополнять своими значениями
float batLevels[] = {4.0, 3.8, 3.6, 3.4}; // 4 порога напряжений
uint8_t levelsCount = sizeof(batLevels) / sizeof(float);

// Символы для отрисовки уровня заряда на дисплее
uint8_t batHeadFull[8]    = {0x1C, 0x1C, 0x1F, 0x1F, 0x1F, 0x1F, 0x1C, 0x1C};
uint8_t batHeadEmpty[8]   = {0x1C, 0x04, 0x07, 0x07, 0x07, 0x07, 0x04, 0x1C};
uint8_t batBodyEmpty[8]   = {0x1F, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x1F};
uint8_t batBottomEmpty[8] = {0x1F, 0x10, 0x10, 0x10, 0x10, 0x10, 0x10, 0x1F};

void showBatLevel(uint8_t);

void setup() {
  analogReference(INTERNAL);
  analogRead(A0); // Холостое считывание после смены опорного напряжения
  lcd.begin();
  lcd.createChar(0, batHeadFull);
  lcd.createChar(1, batHeadEmpty);
  lcd.createChar(2, batBodyEmpty);
  lcd.createChar(3, batBottomEmpty);
}

void loop() {
  lcd.clear();
  lcd.print("Battery level:");
  // Измеряем напряжение на A0
  float v = (float) (analogRead(A0) * Vref / 1024) / divider;
  
  // Определяем уровень заряда по шкале от 0(максимальный уровень) до levelsCount
  uint8_t level = 0;
  while (level < levelsCount) {
    if (v > batLevels[level]) break;
    level++;
  }

  // Покажем уровень заряда
  lcd.setCursor(0, 1);
  showBatLevel(level);

  // и измеренное напряжение 
  lcd.print("  (");
  lcd.print(v);
  lcd.print("v)");
  delay(2000);
}

void showBatLevel(uint8_t level) {
  // Графическое отображение уровня заряда на текстовом дисплее
  // Подходит для отображения 5 уровней
  if (level == 0) {
    lcd.print("xFFxFFxFFxFF");
    lcd.write(0);
  }
  else if (level == 1) {
    lcd.print("xFFxFFxFFxFF");
    lcd.write(1);
  }
  else if (level == 2) {
    lcd.print("xFFxFFxFF");
    lcd.write(2);
    lcd.write(1);
  }
  else if (level == 3) {
    lcd.print("xFFxFF");
    lcd.write(2);
    lcd.write(2);
    lcd.write(1);
  }
  else if (level == 4) {
    lcd.print("xFF");
    lcd.write(2);
    lcd.write(2);
    lcd.write(2);
    lcd.write(1);
  }
  else if (level == 5) {
    lcd.write(3);
    lcd.write(2);
    lcd.write(2);
    lcd.write(2);
    lcd.write(1);
  }
}

На фото видно, что результат измерения напряжения при помощи Ардуино и делителя не сильно отличается от того значения, что показывает мультиметр. Это хороший результат.

При подключении делителя я отказался от макетной платы в пользу пайки, чтобы избежать увеличения сопротивлений из-за плохого контакта.

Опорное напряжение, выдаваемое внутренним стабилизатором, не обязательно будет 1.1 В, и может отличаться от одного микроконтроллера к другому. Даташит допускает разброс от 1.0 до 1.2 В. Поэтому для получения более точных измерений можно вычислить значение Vref и использовать его в скетче при расчетах. Его легко найти путём измерения заранее известного напряжения (обозначим его как V(A0)):

Vref = V(A0) * 1024 /  analogRead(A0)

Вариант 2. Использование датчика напряжения INA219.

После шаманства со всеми этими делителями и внутренними источниками опорного напряжения преимущество датчиков напряжения на базе специализированных микросхем очевидно. Они позволяют измерять напряжение (а некоторые ещё и потребляемый устройством ток) в широком диапазоне и с высокой точностью. INA219 – хороший пример такого датчика. Он потребляет не более 1мА, а в спящем режиме менее 15мкА, что весьма ценно при создании автономных устройств, в условиях энергосбережения. Подробное описание датчика и используемой далее библиотеки для работы с ним вы найдёте здесь: https://compacttool.ru/datchik-napryazheniya-i-toka-na-chipe-ina219

Для отслеживания уровня заряда аккумулятора 18650 при помощи INA219 и вывода результата на дисплей я соединил компоненты в соответствии со схемой:

В этот раз я решил выделить 10 уровней заряда, чтобы отображать его в процентах. Скетч и результат его работы ниже:

#include "Wire.h"
#include "LiquidCrystal_I2C.h"
#include "INA219_WE.h"
LiquidCrystal_I2C lcd(0x27, 16, 2);
INA219_WE ina219(0x40); // 0x40 - I2C адрес модуля

// Пороговые напряжения для 18650. Можно изменять/дополнять своими значениями
float batLevels[] = {4.15, 4.0, 3.82, 3.76, 3.65, 3.6, 3.5, 3.4, 3.3, 3.0};
uint8_t levelsCount = sizeof(batLevels) / sizeof(float);

void setup() {
  lcd.begin();
  ina219.init();
  ina219.setADCMode(BIT_MODE_12); // Устанавливаем разрешение АЦП 12 бит
  ina219.setPGain(PG_40); // Ток в пределах 400 мА
  ina219.setBusRange(BRNG_16); // Напряжение до 16 В
}

void loop() {
  float shuntVoltage_mV = 0.0;
  float loadVoltage_V = 0.0;
  float busVoltage_V = 0.0;

  shuntVoltage_mV = ina219.getShuntVoltage_mV();
  busVoltage_V = ina219.getBusVoltage_V();
  loadVoltage_V  = busVoltage_V + (shuntVoltage_mV / 1000);
  
  // Определяем уровень заряда по шкале от 0(максимальный уровень) до levelsCount
  uint8_t level = 0;
  while (level < levelsCount) {
    if (loadVoltage_V > batLevels[level]) break;
    level++;
  }

  lcd.clear();
  lcd.print("Battery level:");
  lcd.setCursor(0, 1);
  lcd.print(100 - level * 10);
  lcd.print("%  (");
  lcd.print(loadVoltage_V);
  lcd.print("v)");
  delay(2000);
}

Заключение

Конечно, предложенный способ не претендует на высокую точность. Существуют специализированные микросхемы мониторинга питания, которые определяют оставшуюся ёмкость аккумулятора с учётом нагрузки и других параметров. Они находят применение в ноутбуках, телефонах и другой портативной технике. Но вряд ли вы найдёте что-то подобное в любительских проектах – не тот уровень. Таким образом, определение уровня заряда аккумулятора по напряжению – приемлемая альтернатива, не требующая серьёзных аппаратных или программных ресурсов.